master
1/**
2 * This file has no copyright assigned and is placed in the Public Domain.
3 * This file is part of the mingw-w64 runtime package.
4 * No warranty is given; refer to the file DISCLAIMER.PD within this package.
5 */
6
7#include <_mingw_mac.h>
8
9#ifndef __arm64ec__
10 .globl __MINGW_USYMBOL(__intrinsic_setjmp)
11 .def __MINGW_USYMBOL(__intrinsic_setjmp); .scl 2; .type 32; .endef
12
13#if defined(_WIN64)
14 .globl __MINGW_USYMBOL(__intrinsic_setjmpex)
15 .def __MINGW_USYMBOL(__intrinsic_setjmpex); .scl 2; .type 32; .endef
16#endif
17
18#if defined(__i386__)
19 .globl __MINGW_USYMBOL(_setjmp3)
20 .def __MINGW_USYMBOL(_setjmp3); .scl 2; .type 32; .endef
21__MINGW_USYMBOL(_setjmp3):
22__MINGW_USYMBOL(__intrinsic_setjmp):
23 movl 4(%esp),%ecx /* jmp_buf */
24 movl %ebp,0(%ecx) /* jmp_buf.Ebp */
25 movl %ebx,4(%ecx) /* jmp_buf.Ebx */
26 movl %edi,8(%ecx) /* jmp_buf.Edi */
27 movl %esi,12(%ecx) /* jmp_buf.Esi */
28 movl %esp,16(%ecx) /* jmp_buf.Esp */
29 movl 0(%esp),%eax
30 movl %eax,20(%ecx) /* jmp_buf.Eip */
31 xorl %eax, %eax
32 retl
33
34#elif defined(__x86_64__)
35 .globl __MINGW_USYMBOL(setjmp)
36 .def __MINGW_USYMBOL(setjmp); .scl 2; .type 32; .endef
37__MINGW_USYMBOL(setjmp):
38__MINGW_USYMBOL(__intrinsic_setjmp):
39 xorq %rdx,%rdx
40__MINGW_USYMBOL(__intrinsic_setjmpex):
41 movq %rdx,(%rcx) /* jmp_buf->Frame */
42 movq %rbx,0x8(%rcx) /* jmp_buf->Rbx */
43 leaq 0x8(%rsp),%rax
44 movq %rax,0x10(%rcx) /* jmp_buf->Rsp */
45 movq %rbp,0x18(%rcx) /* jmp_buf->Rbp */
46 movq %rsi,0x20(%rcx) /* jmp_buf->Rsi */
47 movq %rdi,0x28(%rcx) /* jmp_buf->Rdi */
48 movq %r12,0x30(%rcx) /* jmp_buf->R12 */
49 movq %r13,0x38(%rcx) /* jmp_buf->R13 */
50 movq %r14,0x40(%rcx) /* jmp_buf->R14 */
51 movq %r15,0x48(%rcx) /* jmp_buf->R15 */
52 movq (%rsp),%rax
53 movq %rax,0x50(%rcx) /* jmp_buf->Rip */
54 stmxcsr 0x58(%rcx) /* jmp_buf->MxCsr */
55 fnstcw 0x5c(%rcx) /* jmp_buf->FpCsr */
56 movdqa %xmm6,0x60(%rcx) /* jmp_buf->Xmm6 */
57 movdqa %xmm7,0x70(%rcx) /* jmp_buf->Xmm7 */
58 movdqa %xmm8,0x80(%rcx) /* jmp_buf->Xmm8 */
59 movdqa %xmm9,0x90(%rcx) /* jmp_buf->Xmm9 */
60 movdqa %xmm10,0xa0(%rcx) /* jmp_buf->Xmm10 */
61 movdqa %xmm11,0xb0(%rcx) /* jmp_buf->Xmm11 */
62 movdqa %xmm12,0xc0(%rcx) /* jmp_buf->Xmm12 */
63 movdqa %xmm13,0xd0(%rcx) /* jmp_buf->Xmm13 */
64 movdqa %xmm14,0xe0(%rcx) /* jmp_buf->Xmm14 */
65 movdqa %xmm15,0xf0(%rcx) /* jmp_buf->Xmm15 */
66 xorq %rax,%rax
67 retq
68
69#elif defined(__arm__)
70__MINGW_USYMBOL(__intrinsic_setjmp):
71 mov r1, #0
72 str r1, [r0] /* jmp_buf->Frame */
73 str r4, [r0, #0x4] /* jmp_buf->R4 */
74 str r5, [r0, #0x8] /* jmp_buf->R5 */
75 str r6, [r0, #0xc] /* jmp_buf->R6 */
76 str r7, [r0, #0x10] /* jmp_buf->R7 */
77 str r8, [r0, #0x14] /* jmp_buf->R8 */
78 str r9, [r0, #0x18] /* jmp_buf->R9 */
79 str r10, [r0, #0x1c] /* jmp_buf->R10 */
80 str r11, [r0, #0x20] /* jmp_buf->R11 */
81 str sp, [r0, #0x24] /* jmp_buf->Sp */
82 str lr, [r0, #0x28] /* jmp_buf->Pc */
83 vmrs r2, fpscr
84 str r2, [r0, #0x2c] /* jmp_buf->Fpscr */
85 vstr d8, [r0, #0x30] /* jmp_buf->D[0] */
86 vstr d9, [r0, #0x38] /* jmp_buf->D[1] */
87 vstr d10, [r0, #0x40] /* jmp_buf->D[2] */
88 vstr d11, [r0, #0x48] /* jmp_buf->D[3] */
89 vstr d12, [r0, #0x50] /* jmp_buf->D[4] */
90 vstr d13, [r0, #0x58] /* jmp_buf->D[5] */
91 vstr d14, [r0, #0x60] /* jmp_buf->D[6] */
92 vstr d15, [r0, #0x68] /* jmp_buf->D[7] */
93 mov r0, #0
94 bx lr
95#elif defined(__aarch64__)
96__MINGW_USYMBOL(__intrinsic_setjmp):
97 mov x1, #0
98__MINGW_USYMBOL(__intrinsic_setjmpex):
99 str x1, [x0] /* jmp_buf->Frame */
100 stp x19, x20, [x0, #0x10] /* jmp_buf->X19, X20 */
101 stp x21, x22, [x0, #0x20] /* jmp_buf->X21, X22 */
102 stp x23, x24, [x0, #0x30] /* jmp_buf->X23, X24 */
103 stp x25, x26, [x0, #0x40] /* jmp_buf->X25, X26 */
104 stp x27, x28, [x0, #0x50] /* jmp_buf->X27, X28 */
105 stp x29, x30, [x0, #0x60] /* jmp_buf->Fp, Lr */
106 mov x2, sp
107 str x2, [x0, #0x70] /* jmp_buf->Sp */
108 mrs x2, fpcr
109 str w2, [x0, #0x78] /* jmp_buf->Fpcr */
110 mrs x2, fpsr
111 str w2, [x0, #0x7c] /* jmp_buf->Fpsr */
112 stp d8, d9, [x0, #0x80] /* jmp_buf->D[0-1] */
113 stp d10, d11, [x0, #0x90] /* jmp_buf->D[2-3] */
114 stp d12, d13, [x0, #0xa0] /* jmp_buf->D[4-5] */
115 stp d14, d15, [x0, #0xb0] /* jmp_buf->D[6-7] */
116 mov x0, #0
117 ret
118#endif
119#endif /* __arm64ec__ */