1/* Startup code compliant to the 64 bit S/390 ELF ABI.
  2   Copyright (C) 2001-2020 Free Software Foundation, Inc.
  3   Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
  4   This file is part of the GNU C Library.
  5
  6   The GNU C Library is free software; you can redistribute it and/or
  7   modify it under the terms of the GNU Lesser General Public
  8   License as published by the Free Software Foundation; either
  9   version 2.1 of the License, or (at your option) any later version.
 10
 11   In addition to the permissions in the GNU Lesser General Public
 12   License, the Free Software Foundation gives you unlimited
 13   permission to link the compiled version of this file with other
 14   programs, and to distribute those programs without any restriction
 15   coming from the use of this file. (The GNU Lesser General Public
 16   License restrictions do apply in other respects; for example, they
 17   cover modification of the file, and distribution when not linked
 18   into another program.)
 19
 20   Note that people who make modified versions of this file are not
 21   obligated to grant this special exception for their modified
 22   versions; it is their choice whether to do so. The GNU Lesser
 23   General Public License gives permission to release a modified
 24   version without this exception; this exception also makes it
 25   possible to release a modified version which carries forward this
 26   exception.
 27
 28   The GNU C Library is distributed in the hope that it will be useful,
 29   but WITHOUT ANY WARRANTY; without even the implied warranty of
 30   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 31   Lesser General Public License for more details.
 32
 33   You should have received a copy of the GNU Lesser General Public
 34   License along with the GNU C Library; if not, see
 35   <https://www.gnu.org/licenses/>.  */
 36
 37#include <sysdep.h>
 38
 39/*
 40   This is the canonical entry point, usually the first thing in the text
 41   segment. Most registers' values are unspecified, except for:
 42
 43   %r14		Contains a function pointer to be registered with `atexit'.
 44		This is how the dynamic linker arranges to have DT_FINI
 45		functions called for shared libraries that have been loaded
 46		before this code runs.
 47
 48   %r15		The stack contains the arguments and environment:
 49		0(%r15)			argc
 50		8(%r15)			argv[0]
 51		...
 52		(8*argc)(%r15)		NULL
 53		(8*(argc+1))(%r15)	envp[0]
 54		...
 55					NULL
 56*/
 57
 58	.text
 59	.globl _start
 60	.type _start,@function
 61_start:
 62	cfi_startproc
 63	/* Mark r14 as undefined in order to stop unwinding here!  */
 64	cfi_undefined (r14)
 65	/* Load argc and argv from stack.  */
 66	la	%r4,8(%r15)		# get argv
 67	lg	%r3,0(%r15)		# get argc
 68
 69	/* Align the stack to a double word boundary.  */
 70	lghi	%r0,-16
 71	ngr	%r15,%r0
 72
 73	/* Setup a stack frame and a parameter area.  */
 74	aghi	%r15,-176		# make room on stack
 75	xc	0(8,%r15),0(%r15)	# clear back-chain
 76
 77	/* Set up arguments for __libc_start_main:
 78	   main, argc, argv, envp, _init, _fini, rtld_fini, stack_end
 79	   Note that envp will be determined later in __libc_start_main.
 80	 */
 81	stmg	%r14,%r15,160(%r15)	# store rtld_fini/stack_end to parameter area
 82	la	%r7,160(%r15)
 83	larl	%r6,__libc_csu_fini	# load pointer to __libc_csu_fini
 84	larl	%r5,__libc_csu_init	# load pointer to __libc_csu_init
 85
 86	/* Ok, now branch to the libc main routine.  */
 87#ifdef PIC
 88	larl	%r2,main@GOTENT		# load pointer to main
 89	lg	%r2,0(%r2)
 90	brasl	%r14,__libc_start_main@plt
 91#else
 92	larl	%r2,main		# load pointer to main
 93	brasl	%r14,__libc_start_main
 94#endif
 95
 96	/* Crash if __libc_start_main returns.	*/
 97	.word	0
 98
 99	cfi_endproc
100
101	/* Define a symbol for the first piece of initialized data.  */
102	.data
103	.globl __data_start
104__data_start:
105	.long 0
106	.weak data_start
107	data_start = __data_start