1/* Startup code compliant to the ELF RISC-V ABI.
 2   Copyright (C) 1995-2025 Free Software Foundation, Inc.
 3   This file is part of the GNU C Library.
 4
 5   The GNU C Library is free software; you can redistribute it and/or
 6   modify it under the terms of the GNU Lesser General Public
 7   License as published by the Free Software Foundation; either
 8   version 2.1 of the License, or (at your option) any later version.
 9
10   In addition to the permissions in the GNU Lesser General Public
11   License, the Free Software Foundation gives you unlimited
12   permission to link the compiled version of this file with other
13   programs, and to distribute those programs without any restriction
14   coming from the use of this file. (The GNU Lesser General Public
15   License restrictions do apply in other respects; for example, they
16   cover modification of the file, and distribution when not linked
17   into another program.)
18
19   Note that people who make modified versions of this file are not
20   obligated to grant this special exception for their modified
21   versions; it is their choice whether to do so. The GNU Lesser
22   General Public License gives permission to release a modified
23   version without this exception; this exception also makes it
24   possible to release a modified version which carries forward this
25   exception.
26
27   The GNU C Library is distributed in the hope that it will be useful,
28   but WITHOUT ANY WARRANTY; without even the implied warranty of
29   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
30   Lesser General Public License for more details.
31
32   You should have received a copy of the GNU Lesser General Public
33   License along with the GNU C Library.  If not, see
34   <https://www.gnu.org/licenses/>.  */
35
36#define __ASSEMBLY__ 1
37#include <entry.h>
38#include <sysdep.h>
39#include <sys/asm.h>
40
41/* The entry point's job is to call __libc_start_main.  Per the ABI,
42   a0 contains the address of a function to be passed to atexit.
43   __libc_start_main wants this in a5.  */
44
45ENTRY (ENTRY_POINT)
46	/* Terminate call stack by noting ra is undefined.  Use a dummy
47	   .cfi_label to force starting the FDE.  */
48	.cfi_label .Ldummy
49	cfi_undefined (ra)
50	call  load_gp
51	mv    a5, a0  /* rtld_fini.  */
52	/* main may be in a shared library.  */
53#if defined PIC && !defined SHARED
54	/* Avoid relocation in static PIE since _start is called before it
55	   is relocated.  */
56	lla   a0, __wrap_main
57#else
58	la   a0, main
59#endif
60	REG_L a1, 0(sp)      /* argc.  */
61	addi  a2, sp, SZREG  /* argv.  */
62	andi  sp, sp, ALMASK /* Align stack. */
63	li    a3, 0	     /* Used to be init.  */
64	li    a4, 0	     /* Used to be fini.  */
65	mv    a6, sp  /* stack_end.  */
66
67	call  __libc_start_main@plt
68	ebreak
69END (ENTRY_POINT)
70
71#if defined PIC && !defined SHARED
72__wrap_main:
73	tail  main@plt
74#endif
75
76/* Dynamic links need the global pointer to be initialized prior to calling
77   any shared library's initializers, so we use preinit_array to load it.
78   This doesn't cut it for static links, though, since the global pointer
79   needs to be initialized before calling __libc_start_main in that case.
80   So we redundantly initialize it at the beginning of _start.  */
81
82load_gp:
83.option push
84.option norelax
85	lla   gp, __global_pointer$
86.option pop
87	ret
88
89	.section .preinit_array,"aw"
90	.align PTRLOG
91	.dc.a load_gp
92
93/* Define a symbol for the first piece of initialized data.  */
94	.data
95	.globl __data_start
96__data_start:
97	.weak data_start
98	data_start = __data_start