master
1/* Copyright (C) 1995-2025 Free Software Foundation, Inc.
2
3 This file is part of the GNU C Library.
4
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
9
10 In addition to the permissions in the GNU Lesser General Public
11 License, the Free Software Foundation gives you unlimited
12 permission to link the compiled version of this file with other
13 programs, and to distribute those programs without any restriction
14 coming from the use of this file. (The GNU Lesser General Public
15 License restrictions do apply in other respects; for example, they
16 cover modification of the file, and distribution when not linked
17 into another program.)
18
19 Note that people who make modified versions of this file are not
20 obligated to grant this special exception for their modified
21 versions; it is their choice whether to do so. The GNU Lesser
22 General Public License gives permission to release a modified
23 version without this exception; this exception also makes it
24 possible to release a modified version which carries forward this
25 exception.
26
27 The GNU C Library is distributed in the hope that it will be useful,
28 but WITHOUT ANY WARRANTY; without even the implied warranty of
29 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
30 Lesser General Public License for more details.
31
32 You should have received a copy of the GNU Lesser General Public
33 License along with the GNU C Library; if not, see
34 <https://www.gnu.org/licenses/>. */
35
36#include <sysdep.h>
37
38/* This is the canonical entry point, usually the first thing in the text
39 segment.
40
41 Note that the code in the .init section has already been run.
42 This includes _init and _libc_init
43
44
45 At this entry point, most registers' values are unspecified, except:
46
47 x0/w0 Contains a function pointer to be registered with `atexit'.
48 This is how the dynamic linker arranges to have DT_FINI
49 functions called for shared libraries that have been loaded
50 before this code runs.
51
52 sp The stack contains the arguments and environment:
53 0(sp) argc
54 8(sp) argv[0]
55 ...
56 (8*argc)(sp) NULL
57 (8*(argc+1))(sp) envp[0]
58 ...
59 NULL
60 */
61
62 .text
63ENTRY(_start)
64 /* Create an initial frame with 0 LR and FP */
65 cfi_undefined (x30)
66 mov x29, #0
67 mov x30, #0
68
69 /* Setup rtld_fini in argument register */
70 mov x5, x0
71
72 /* Load argc and a pointer to argv */
73 ldr x1, [sp, #0]
74 add x2, sp, 8
75
76 /* Setup stack limit in argument register */
77 mov x6, sp
78
79#ifdef PIC
80# ifdef SHARED
81 adrp x0, :got:main
82 ldr x0, [x0, #:got_lo12:main]
83# else
84 adrp x0, __wrap_main
85 add x0, x0, :lo12:__wrap_main
86# endif
87#else
88 movz x0, :abs_g3:main
89 movk x0, :abs_g2_nc:main
90 movk x0, :abs_g1_nc:main
91 movk x0, :abs_g0_nc:main
92#endif
93 mov x3, #0 /* Used to be init. */
94 mov x4, #0 /* Used to be fini. */
95
96 /* __libc_start_main (main, argc, argv, init, fini, rtld_fini,
97 stack_end) */
98
99 /* Let the libc call main and exit with its return code. */
100 bl __libc_start_main
101
102 /* should never get here....*/
103 bl abort
104
105#if defined PIC && !defined SHARED
106 /* When main is not defined in the executable but in a shared library
107 then a wrapper is needed in crt1.o of the static-pie enabled libc,
108 because crt1.o and rcrt1.o share code and the later must avoid the
109 use of GOT relocations before __libc_start_main is called. */
110__wrap_main:
111 bti c
112 b main
113#endif
114END(_start)
115
116 /* Define a symbol for the first piece of initialized data. */
117 .data
118 .globl __data_start
119__data_start:
120 .long 0
121 .weak data_start
122 data_start = __data_start